#! /usr/bin/perl

#  infocon - Administration tool for InfoCon
#  Copyright (c) 1998-2003,2005-8,10,11,12,14,15,16,18  Martin Schulze <joey@infodrom.org>
#
#  This program is free software; you can redistribute it and/or modify
#  it under the terms of the GNU General Public License as published by
#  the Free Software Foundation; either version 2 of the License, or
#  (at your option) any later version.
#
#  This program is distributed in the hope that it will be useful,
#  but WITHOUT ANY WARRANTY; without even the implied warranty of
#  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
#  GNU General Public License for more details.
#
#  You should have received a copy of the GNU General Public License
#  along with this program; if not, write to the Free Software
#  Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111, USA.

use strict;
use warnings;

use DBI;
use Scalar::Util qw/reftype/;
use Term::ReadLine;
use Getopt::Long;

my $table = "sales";
my $engine  = "dbi:Pg:dbname=infocon";
my $dbh = DBI->connect($engine);
if (!$dbh) {
    print "Access to database denied!\n";
    return 1;
}

my %data;
my @categories = ();
my $term = undef;
my $opt_all = 0;
my $opt_csv = 0;
my $opt_verbose = 0;
my $opt_year = 0;
my $opt_date = undef;
my $opt_grep = undef;
my $opt_direction = undef;

sub sdate
{
    $_[0] =~ /\d{2}(\d{2})(\d{2})(\d{2})/;
    return sprintf ("%d.%02d.%02d", $3,$2,$1);
}

sub isodate
{
    $_[0] =~ /(\d{4})(\d{2})(\d{2})/;
    return sprintf ("%04d-%02d-%02d", $1,$2,$3);
}

# Wandelt einen lesbaren Datumsstring in die Form um, in der er in der
# Datenbank gespeichert werden kann.
#
sub date_to_string
{
    my ($day,$mon,$year);

    return "" if (!$_[0]);

    my ($date_sec,$date_min,$date_hour,$date_mday,$date_mon,$date_year,$date_wday,$date_isdst)
	= localtime;

    if ($_[0] eq "heute" || $_[0] eq "sofort" || $_[0] eq "pronto" || $_[0] eq "today" || $_[0] eq "now") {
	$day = $date_mday;
	$mon = $date_mon+1;
	$year = $date_year;
    } elsif ($_[0] eq "gestern" || $_[0] eq "yesterday") {
	$day = $date_mday-1 if ($date_mday);
	$mon = $date_mon+1;
	$year = $date_year;
    } elsif ($_[0] eq "morgen" || $_[0] eq "tomorrow") {
	$day = $date_mday+1;
	$mon = $date_mon+1;
	$year = $date_year;
    } else {
	($day,$mon,$year) = split(/\./, $_[0]);
	if (!$year) {    
	    $year = $date_year;
	}
    }

    if ($year < 70) {
	$year += 2000;
    } elsif ($year < 100) {
	$year += 1900;
    }
    return sprintf("%4d%02d%02d", $year,$mon,$day);
}

sub valid_isodate
{
    my $date = shift;
    my ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) = localtime(time);

    return sprintf('%04d-%02d-%02d', $year+1900, $mon+1, $mday) unless defined $date;

    if ($date =~ /^(\d+)\.(\d+)\.?$/) {
	if ($mon == 0 && $2 > 9) {
	    $date = sprintf('%04d-%02d-%02d', $year+1900-1, $2, $1);
	} else {
	    $date = sprintf('%04d-%02d-%02d', $year+1900, $2, $1);
	}
    } elsif ($date =~ /^(\d+)\.(\d+)\.(\d+)?$/) {
	if (length $3 == 2) {
	    $date = sprintf('20%02d-%02d-%02d', $3, $2, $1);
	} else {
	    $date = sprintf('%04d-%02d-%02d', $3, $2, $1);
	}
    } elsif ($date !~ /^(\d+)-(\d+)-(\d+)$/) {
	return undef;
    }
    return $date;
}

sub pay_invoice
{
    my $nr = shift;
    my $pay = shift;
    my $query;
    my $sth;

    if ($pay) {
	my $date = valid_isodate $opt_date;

	die "Invalid date\n" unless defined $date;

	$query  = sprintf("UPDATE sales SET paid=1,billing_date=%s WHERE nr = %d",
			  defined $date ? $dbh->quote($date) : 'now()', $nr);
    } else {
	$query  = sprintf("UPDATE sales SET paid=0,billing_date=NULL WHERE nr = %d", $nr);
    }
    $sth = $dbh->do($query);
}

sub hide_invoice
{
    my $nr = shift;
    my $hide = shift;
    my $value = $hide==1?0:1;
    my $query;
    my $sth;

    $query  = "UPDATE sales SET visible=$value WHERE nr = $nr";
    $sth = $dbh->do($query);
}

sub sales_list
{
    my $where = shift;
    my $descr;
    my $sum_pos=0;
    my $sum_neg=0;
    my $query;
    my $row;
    my $sth;
    my $d;

    if ($where && $where !~ /visible/ && (!$opt_all || $opt_all == 0)) {
	if ($where) {
	    $where .= " AND visible = 1";
	} else {
	    $where .= "visible = 1";
	}
    }

    if ($opt_year) {
	$where .= " AND " if $where;
	$where .= sprintf("year = %d", $opt_year);
    }

    if (defined $data{category} && length $data{category}) {
	$where .= " AND " if $where;
	$where .= sprintf("category = %s", $dbh->quote($data{category}));
    }

    if ($opt_direction) {
	if ($opt_direction eq "in") {
	    $d = "price >= 0"
	} elsif ($opt_direction eq "out") {
	    $d = "price <= 0"
	}

	if ($where) {
	    $where .= " AND $d";
	} else {
	    $where .= "$d";
	}
    }

    if ($opt_grep) {
	$where .= " AND " if $where;
	$where .= sprintf("description ILIKE '%%%s%%'", $opt_grep);
    }

    if ($where !~ /visible/) {
	$where .= " AND " if $where;
	$where .= "visible = 1";
    }

    $query  = "SELECT nr,date,description,price,tax_percent,tax_assigned FROM $table";
    $query .= " WHERE $where" if ($where);
    $query .= " ORDER by date,nr";

    $sth = $dbh->prepare($query);
    if ($sth && (my $rc = $sth->execute) > 0) {
	if ($opt_csv) {
	    print '"nr","date","description","taxrate","tax","value"'."\n";
	} else {
	    print " Nr.   Datum  Bezeichnung                                           Betrag\n";
	    print "----------------------------------------------------------------------------\n";
	}
	while ($row = $sth->fetchrow_hashref) {
	    $descr = substr($row->{description},0,50);
	    if ($opt_csv) {
		printf '"%d","%s","%s","%.2f","%.2f","%.2f"'."\n", $row->{nr}, isodate($row->{date}), $descr,
		    $row->{tax_percent}, $row->{tax_assigned}, $row->{price};
	    } else {
		printf "%4d %8s %-50s  %9.2f\n", $row->{nr}, sdate($row->{date}), $descr, $row->{price};
	    }
	    if ($row->{price} < 0.0) {
		$sum_neg -= $row->{price};
	    } else {
		$sum_pos += $row->{price};
	    }
	}
	if (!$opt_csv) {
	    print "---------------------------------------------------------------------------\n"
		if ($sum_neg > 0 || $sum_pos > 0) ;
	    printf " Zahlungseingänge                                                 %9.2f\n", $sum_pos
		if ($sum_pos > 0);
	    printf " Zahlungsausgänge                                                 %9.2f\n", -$sum_neg
		if ($sum_neg > 0);
	    print "============================================================================\n";
	    printf " Summe                                                            %9.2f\n\n", $sum_pos - $sum_neg;
	}
    }
    $data{'done'} = 1;
}

sub get_categories
{
    my $query;
    my @row;
    my $sth;
    my @arr = ();

    $query  = "SELECT DISTINCT category FROM $table ORDER by category";
    $sth = $dbh->prepare($query);
    if ($sth && (my $rc = $sth->execute) > 0) {
	while (@row = $sth->fetchrow_array) {
	    push(@arr, $row[0]) if ($row[0]);
	}
    }
    return @arr;
}

sub list_categories
{
    my $field = shift;
    my $answers = shift;

    @categories = get_categories unless @categories;

    printf "%s\n", join (", ",@categories);

    exit unless $field;
}

sub validate_date
{
    my $ans = shift;
    my ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) = localtime(time);

    return sprintf("%d.%d.%d", $mday, $mon+1, $year+1900) unless length $ans;

    my @arr = split(/\./, $ans);

    return sprintf("%d.%d.%d", $ans, $mon+1, $year+1900) if scalar @arr == 1;
    return sprintf("%d.%d.%d", $arr[0], $arr[1], $year+1900) if scalar @arr == 2;
    return sprintf("%d.%d.%d", $arr[0], $arr[1],
		   length $arr[2] > 2 ? $arr[2] : $arr[2] + 2000);
}

my $answers;
sub calculate_price
{
    my $ans = shift;

    if (!defined $answers->{tax_assigned} || !length $answers->{tax_assigned}) {
	$answers->{tax_assigned} = $ans - ($ans / ((100+$answers->{tax_percent})/100));
    }

    if ($answers->{einaus} =~ /[ei]/i) {
	$answers->{tax_assigned} *= -1 if $answers->{tax_assigned} < 0;
	$ans *= -1 if $ans < 0;
    } else {
	$answers->{tax_assigned} *= -1 if $answers->{tax_assigned} > 0;
	$ans *= -1 if $ans > 0;
    }

    return $ans;
}

sub complete_category
{
    my ($text, $line, $start) = @_;

    return () unless exists $answers->{category} && length $answers->{category};

    my $sql = sprintf("SELECT DISTINCT description FROM %s WHERE category = '%s' AND description LIKE '%s%%' ORDER BY description",
		      $table,
		      $answers->{category},
		      $line);
    my $sth = $dbh->prepare($sql);
    $sth->execute;
    my @complete;
    while (my $row = $sth->fetchrow_hashref) {
	$row->{description} = substr $row->{description}, $start if $start;
	push @complete, $row->{description};
    }

    return @complete;
}

sub complete_categoryname
{
    my ($text, $line, $start) = @_;

    return () unless length $line;

    my $sql = sprintf("SELECT DISTINCT category FROM %s WHERE category LIKE '%s%%' ORDER BY category",
		      $table,
		      $line);
    my $sth = $dbh->prepare($sql);
    $sth->execute;
    my @complete;
    while (my $row = $sth->fetchrow_hashref) {
	$row->{category} = substr $row->{category}, $start if $start;
	push @complete, $row->{category};
    }

    return @complete;
}

sub default_year
{
    my $answers = shift;

    my @arr = split(/\./, $answers->{date});
    return $arr[2];
}

sub read_input
{
    my $name = shift;
    my $info = shift;
    my $default;
    my $ans;

    if (exists $info->{default}) {
	if ($info->{default} eq 'last') {
	    $default = $answers->{$name} if $answers->{$name};
	} elsif (reftype $info->{default} && reftype $info->{default} eq 'CODE') {
	    $default = $info->{default}($answers);
	} elsif ($info->{type} && $info->{type} eq 'boolean') {
	    if ($info->{default}) {
		$default = 'J';
	    } else {
		$default = 'N';
	    }
	} else {
	    $default = $info->{default};
	}
    }

    if ($info->{complete}) {
	$term->{completion_function} = $info->{complete};
    } else {
	$term->{completion_function} = undef;
    }

    if ($default) {
	$ans = $term->readline ($info->{title} . " [" . $default . "]: ");
    } else {
	$ans = $term->readline ($info->{title} . ": ");
    }

    exit unless defined $ans;

    if (!length $ans && defined $default) {
	$ans = $default;
    } elsif ($ans eq ".") {
	$ans = '';
    }

    return read_input($name, $info) unless length $ans || exists $info->{empty};

    if ($ans eq '?' && exists $info->{lookup}) {
	$info->{lookup}($name, $answers);
	return read_input($name, $info);
    }

    if (exists $info->{type} && $info->{type} eq 'boolean') {
	if ($ans =~ /[JY1]/i) {
	    $ans = 1;
	} else {
	    $ans = 0;
	}
    } elsif (exists $info->{validate} && reftype $info->{validate} eq 'CODE') {
 	$ans = $info->{validate}($ans);
    } else {
	$ans =~ s/ *$// if $ans;
    }

    if (!exists $info->{type} || $info->{type} ne 'boolean') {
	$term->addhistory($ans);
    }

    return $ans;
}

# Gibt die naechste freie Nr. in der Datenbank zurueck.  Wenn der
# INSERT nicht schnell darauf folgt, kann es passieren, dass die
# Nr. anschliessend bereits wieder vergeben ist.
#
sub get_next_nr
{
    my $query;
    my $sth;
    my $rc;
    my @row;

    $query = "SELECT nr FROM $table ORDER BY nr DESC";
    $sth = $dbh->prepare($query);
    if ($sth) {
	$rc = $sth->execute;
	if ($rc > 0 && (@row = $sth->fetchrow_array)) {
	    return $row[0] + 1;
	}
    }
    return 1;
}

sub buchung_input
{
    my $weiter = 'y';
    my $ans;
    my ($date_sec,$date_min,$date_hour,$date_mday,$date_mon,$date_year,$date_wday,$date_isdst)
	= localtime;

    my $fields = {
	'date' => {
	    'title' => 'Datum',
	    'validate' => \&validate_date,
	    'default' => 'last'},
	'pdf' => {
	    'title' => 'PDF',
	    'type' => 'boolean',
	    'default' => 0},
	'year' => {
	    'title' => 'Jahr',
	    'default' => \&default_year},
	'category' => {
	    'title' => 'Kategorie',
	    'lookup' => \&list_categories,
	    'default' => 'last',
	    'complete' => \&complete_categoryname},
	'description' => {
	    'title' => 'Beschreibung',
	    'default' => 'last',
	    'complete' => \&complete_category},
	'einaus' => {
	    'title' => 'Ein/Aus',
	    'default' => 'a',
	    'save' => 0},
	'tax_percent' => {
	    'title' => 'Steuersatz',
	    'default' => '19'},
	'tax_assigned' => {
	    'title' => 'Umsatzsteuer',
	    'empty' => 1},
	'price' => {
	    'title' => 'Betrag',
	    'validate' => \&calculate_price},
	'paid' => {
	    'title' => 'bezahlt',
	    'type' => 'boolean',
	    'default' => 0},
	'billing_date' => {
	    'title' => 'wann',
	    'type' => 'date',
	    'validate' => \&validate_date},
	'weiter' => {
	    'title' => 'Weiter',
	    'type' => 'boolean',
	    'default' => 1,
	    'save' => 0},
    };
    my @fields = ('date','year','pdf','category','description','einaus','tax_percent','tax_assigned','price','paid','weiter');

    @categories = get_categories unless @categories;

    $term = new Term::ReadLine '' unless $term;

    my $sth = $dbh->prepare ("INSERT INTO $table (nr,date,pdf,year,category,description,tax_percent,tax_assigned,price,billing_date,paid) " .
			     "VALUES (?,?,?,?,?,?,?,?,?,?,?)");

    print "Buchungseingabe\n\n";
    while ($weiter =~ /[JjYy1]/) {
	foreach my $f (@fields) {
	    if ($f eq 'tax_assigned' && $answers->{'tax_percent'} == 0) {
		$answers->{$f} = 0;
		next;
	    }
	    $ans = read_input($f, $fields->{$f});
	    $answers->{$f} = $ans;

	    if ($f eq 'paid') {
		if ($answers->{paid}) {
		    $fields->{'billing_date'}{'default'} = $answers->{'date'};
		    $ans = read_input('billing_date', $fields->{'billing_date'});
		    $answers->{billing_date} = $ans;
		} else {
		    $answers->{billing_date} = undef;
		}
	    }
	}

	$sth->execute(get_next_nr(),
		      date_to_string($answers->{date}),
		      $answers->{pdf},
		      $answers->{year},
		      $answers->{category},
		      $answers->{description},
		      $answers->{tax_percent},
		      $answers->{tax_assigned},
		      $answers->{price},
		      defined $answers->{billing_date} ? date_to_string($answers->{billing_date}) : undef,
		      $answers->{paid});

	$weiter = $answers->{weiter};
	$answers->{tax_assigned} = 0.0;
    }

    exit;
}

sub buchung_hidden
{
    $table = "sales_dm";
    sales_list("visible = 0");
    $table = "sales";
    sales_list("visible = 0");
    exit;
}

sub buchung_unpaid
{
    $table = "sales";
    sales_list("paid = 0");
    exit;
}

sub usage
{
    print "infocon [options] [-h|--help] commands\n";
    print "  --buchung-category|-bc [category]\n";
    print "  --buchung-input|-bi\n";
    print "  --buchung-unpaid|-bu\n";
    print "  --buchung-hidden\n";
    print "  --date [yyyy-mm-dd|dd.mm.] (for --pay)\n";
    print "  --pay <nr> | --unpay <nr>\n";
    print "  --hide <nr> | --unhide <nr>\n";
    print "  --list-categories|-lc\n";
    print "  Options:\n";
    print "    --all|-a\n";
    print "    --csv\n";
    print "    --verbose|-v\n";
    print "    --grep|-g keyword\n";
    print "    --year|-y year\n";
    print "    --direction|--dir|-d in|out\n";
    print "    --dm\n";
    exit 0;
}

%data = (
    'category' => undef,
    'done' => undef,
    'pay' => undef,
    'unpay' => undef,
    'hide' => undef,
    'unhide' => undef,
    'mailto' => undef,
    'buchung-input' => undef,
    'buchung-unpaid' => undef,
    'buchung-hidden' => undef,
    'list-categories' => undef,
    );
my %options = (
    'buchung-category|bc:s' => \$data{category},
    'pay=s' => \$data{pay},
    'unpay=s' => \$data{unpay},
    'hide=s' => \$data{hide},
    'unhide=s' => \$data{unhide},
    'year=i' => \$opt_year,
    'date=s' => \$opt_date,
    'direction|d=s' => \$opt_direction,
    'grep|g=s' => \$opt_grep,
    'mailto:s' => \$data{mailto},
    'all' => \$opt_all,
    'csv' => \$opt_csv,
    'verbose' => \$opt_verbose,
    'help' => \&usage,
    'dm' => sub {$table = "sales_dm"},
    'buchung-input|bi' => \&buchung_input,
    'buchung-unpaid|bu' => \&buchung_unpaid,
    'buchung-hidden|bh' => \&buchung_hidden,
    'list-categories|lc' => \$data{'list-categories'},
    );

my $cmdln = 'infocon ' . join (' ', @ARGV);
GetOptions(%options);

if ($opt_year != 0 && $opt_year < 2002) {
    $table = "sales_dm";
}

if (defined $opt_direction) {
    usage unless $opt_direction =~ /^(in|out)$/i;
}

if (defined $data{mailto}) {
    if (open(STDOUT, "| /usr/sbin/sendmail -t")) {
	print  "From: Joey Schulze <joey\@infodrom.org>\n";
	printf "To: %s\n", length($data{mailto})?$data{mailto}:'Joey Schulze <joey@infodrom.org>';
	printf "Subject: %s\n", $cmdln;
	print  "MIME-Version: 1.0\n";
	print  "Content-type: text/plain; charset=iso-8859-1\n";
	print  "Content-Disposition: inline\n";
	print  "Content-Transfer-Encoding: 8bit\n";
	print  "\n";
    }
}

if (defined $data{category}) {
    sales_list;
    exit;
} elsif (defined $data{'list-categories'}) {
    list_categories;
} elsif (defined $data{pay}) {
    pay_invoice($data{pay}, 1);
} elsif (defined $data{unpay}) {
    pay_invoice($data{unpay}, 0);
} elsif (defined $data{hide}) {
    hide_invoice($data{hide}, 1);
} elsif (defined $data{unhide}) {
    hide_invoice($data{unhide}, 0);
} else {
    usage;
}